[VB.NET] Gestire documenti Word con Interop

Descrizione :
Un semplice esempio di Report dati su Word 2007 con Microsoft.Office.Interop.

+ Articolo :

Unico Rif. richiesto è nei Riferimenti .NET : Microsoft.Office.Interop.Word v12.0.0.0.
L'esempio seguente crea un'Application Word, aggiunge un nuovo Document, e inserisce una Tabella Dati a runtime.

Seguono le operazioni di salvataggio / chiusura oggetti e relativo rilascio risorse con Marshal.ReleaseComObject().

--> Codice Esempio :

        'Esempio con Word 2007 :
        'RIF. a Microsoft.Office.Interop.Word v12.0.0.0 
        'Office 12 = Office 2007 / Office 14 = Office 2010

        'Percorso relativo Documents
        Dim percorso As String = Application.StartupPath & "\"

        'Applicazione Word : UNA sola per tutti i Documents
        'coinvolti nell'operazione
        Dim AppWord As New Microsoft.Office.Interop.Word.Application

        'Visibilità Applicazione Word
        AppWord.Visible = False

        'Oggetto Document
        Dim nomeFileOutput As String = "outputTable.docx"
        Dim wordDoc As Microsoft.Office.Interop.Word.Document
        wordDoc = AppWord.Documents.Add

        'Operazioni
        'Creazione Range 
        'wordDoc.Range = primo Range disponibile
        'in caso di bookmark usare wordDoc.Bookmarks(indice/nome As Object).Range
        Dim R As Microsoft.Office.Interop.Word.Range = wordDoc.Range
        'Creazione Tabella con Riga intestazione
        Dim T As Microsoft.Office.Interop.Word.Table = wordDoc.Tables.Add(R, 1, 5)
        T.Rows(1).Range.Bold = 1
        T.Cell(1, 1).Range.Text = "Colonna A"
        T.Cell(1, 2).Range.Text = "Colonna B"
        T.Cell(1, 3).Range.Text = "Colonna C"
        T.Cell(1, 4).Range.Text = "Colonna D"
        T.Cell(1, 5).Range.Text = "Colonna E"
        'Formattazione generale Tabella
        T.AutoFitBehavior(Microsoft.Office.Interop.Word.WdAutoFitBehavior.wdAutoFitWindow)
        T.Borders.OutsideLineStyle = Microsoft.Office.Interop.Word.WdLineStyle.wdLineStyleSingle
        T.Borders.InsideLineStyle = Microsoft.Office.Interop.Word.WdLineStyle.wdLineStyleSingle
        'Dati esempio : aggiunta di 10 righe di dati
        For i As Integer = 1 To 10
            T.Rows.Add()
            T.Rows(i + 1).Range.Bold = 0
            T.Cell(i + 1, 1).Range.Text = "Cella A" & i
            T.Cell(i + 1, 2).Range.Text = "Cella B" & i
            T.Cell(i + 1, 3).Range.Text = "Cella C" & i
            T.Cell(i + 1, 4).Range.Text = "Cella D" & i
            T.Cell(i + 1, 5).Range.Text = "Cella E" & i
        Next

        'Salvataggio / Chiusura Oggetti
        wordDoc.SaveAs(percorso & nomeFileOutput)
        wordDoc.Close()
        System.Runtime.InteropServices.Marshal.ReleaseComObject(wordDoc)

        'Chiusura Applicazione Word
        AppWord.Quit()
        System.Runtime.InteropServices.Marshal.ReleaseComObject(AppWord)

        MessageBox.Show("Processo completato.", "OK", MessageBoxButtons.OK, MessageBoxIcon.Information)

La Tabella Dati è solo d'esempio, ma con poche modifiche non è difficile ridattare il codice a casi di compilazione da dati reali provenienti da interrogazioni a DB : DataReader, cicli di lettura da DataSet, DataTable, DataView, DataGridView, ecc ...

+ Fine Articolo.

---

Un Click su "Mi Piace" è il modo migliore per ringraziare l'autore di questo articolo.

---

Posted in: VB.NET